NASM 32 - CONVERSION HEXA / DÉCIMAL => DIVISION (32 BITS) PAR 10

Commentaire de ToutEnMasm le 25/09/2004 16:43:52

salut,
La méthode de masm32 pour passer d'un DW a une chaine de caractere ascii, dwtoa
                          ToutEnMasm
                          

; #########################################################################

  ; ---------------------------------------------------------------
  ;      This procedure was originally written by Tim Roberts
  ;
  ; Part of this code has been optimised by Alexander Yackubtchik
  ; ---------------------------------------------------------------

    .386
    .model flat, stdcall  ; 32 bit memory model
    option casemap :none  ; case sensitive

    .code

; #########################################################################

dwtoa proc dwValue:DWORD, lpBuffer:DWORD
        
    ; -------------------------------------------------------------
    ; convert DWORD to ascii string
    ; dwValue is value to be converted
    ; lpBuffer is the address of the receiving buffer
    ; EXAMPLE:
    ; invoke dwtoa,edx,ADDR buffer
    ;
    ; Uses: eax, ecx, edx.
    ; -------------------------------------------------------------

    push ebx
    push esi
    push edi

    mov eax, dwValue
    mov edi, [lpBuffer]

    or eax,eax
    jnz sign
    
  zero:
    mov word ptr [edi],30h
    jmp dw2asc
    
  sign:
    jns pos
    mov byte ptr [edi],'-'
    neg eax
    inc edi

  pos:      
    mov ecx,429496730
    mov esi, edi

    .while (eax > 0)
      mov ebx,eax
      mul ecx
      mov eax,edx
      lea edx,[edx*4+edx]
      add edx,edx
      sub ebx,edx
      add bl,'0'
      mov [edi],bl
      inc edi
    .endw

    mov byte ptr [edi], 0       ; terminate the string

    ; We now have all the digits, but in reverse order.

    .while (esi < edi)
      dec edi
      mov al, [esi]
      mov ah, [edi]
      mov [edi], al
      mov [esi], ah
      inc esi
    .endw

    dw2asc:

    pop edi
    pop esi
    pop ebx

    ret

dwtoa endp

; #########################################################################

end

Commentaire de Nikro le 26/09/2004 00:45:39

Merci pour ces commentaires qui contriburont à m'orienter vers une meilleure vision des choses.
C'est ma première routine en assembleur, excepté le Hello World de prise en main.
J'essaie en fait de programmer un convertisseur multi-base pour me familiariser avec l'assembleur.
Visiblement ça prendra du temps, je le prendrai.
@++.

Commentaire de BruNews le 28/09/2004 18:50:25 administrateur CS

Vaut mieux faire un 'mul' que un 'div' si on connait le diviseur. Vois que dans le dwtoa de MASM32 c'est aussi fait de cette maniere, avec d'autres valeurs mais le but est toujours de mettre un mul au lieu d'un div.